Canonical Embeddings of Plane Curves and Gonality
\beginsection{ MATHEMATICAL BACKGROUND}\par
\def\P{\bf P}
The gonality of a curve is defined to be
the smallest degree of a morphism from the
curve to the projective line $\P^1$.
It is known that a curve $C$ of genus $g$
admits a map to $\P^1$ of degree at most
$[(g+3)/2]$. Further, if $C$ is $d$-gonal,
then in its canonical embedding $C$
lies on a rational normal scroll of
dimension $d-1$, and the free resolution
of the homogeneous coordinate ring of the
scroll is a subcomplex of the
free resolution of the homogeneous coordinate
ring of $C$. Thus
for example the $2$-linear part of that
resolution has length at least $g-d$, and
``Green's Conjecture'' states that if one
computes Clifford index instead of gonality,
a slight refinement, then equality holds.
For example, Green's conjecture predicts
that the resolution of the homogeneous
coordinate ring of a general curve of
genus 7 and gonality 4 is:
-- total: 1 10 25 25 10 1
-- 0: 1 . . . . .
-- 1: . 10 16 9 . .
-- 2: . . 9 16 10 .
-- 3: . . . . . 1 (Green's conjecture has actually been proven
by Frank Schreyer in this case; in any case
the result that the two-linear part is AT LEAST
as long as predicted in Green's conjecture is
easy.)
If a curve can be represented as a plane curve
of degree $e$ with an ordinary multiple point
(that is, the branches have distinct tangents)
of multiplicity $m$, then projection from the
point defines a map to $\P^1$ of degree $e-m$.
In this example we will illustrate the
``principle'' that this is often the gonality
of the curve by computing the canonical
embedding and its resolution. To compute the
canonical embedding, we will use ``adjunction'':
the canonical
series of a plane curve $C$ of degree $e$ with
only ordinary multiple points of degrees $m_i$
as singularities is obtained as the
linear series cut out by plane curves $D$ of degree
$e-3$ passing through the nodes with multiplicities
$m_i-1$; at a tacnode of multiplicity 2 the
condition is that $D$ passes through the
singular point and is tangent to the
tangent line of $C$ at that point.
We will make these computations for three
types of plane sextic curves (of genus seven):
{\tt C1} will have 3 ordinary nodes;
{\tt C2} will have one ordinary triple point;
{\tt C3} will have one tacnode and one ordinary node.
\beginsection{ Computation}\par
We take {\tt C1} to be a curve of degree $6$
having $3$ ordinary double points:
i1 : R = ZZ/31991[a,b,c] -- the coordinate ring of P^2
o1 = R
o1 : PolynomialRing |
We define the ideals of the points.
We could write
i2 : ipoint1 = ideal matrix({{a,b}})
o2 = ideal (a, b)
o2 : Ideal of R |
but the following shortcut is faster!
i3 : ipoint1 = ideal(a,b)
o3 = ideal (a, b)
o3 : Ideal of R |
i4 : ipoint2 = ideal(a,c)
o4 = ideal (a, c)
o4 : Ideal of R |
i5 : ipoint3 = ideal(b,c)
o5 = ideal (b, c)
o5 : Ideal of R |
For a curve to be double at the $3$ points,
its equation must lie in the ideal
i6 : icurves1 = intersect(
ipoint1^2,
ipoint2^2,
ipoint3^2
)
2 2 2 2 2 2
o6 = ideal (a*b*c, b c , a c , a b )
o6 : Ideal of R |
The matrix with the generators of {\tt icurves1}
as its entries is obtained by
i7 : Icurves1 = gens icurves1
o7 = {0} | abc b2c2 a2c2 a2b2 |
1 4
o7 : Matrix R <--- R |
We find the equation {\tt F1} of a general curve
of degree $6$ with these double points by
composing a random matrix of forms having
the correct degree with the matrix of
generators of {\tt icurves1}.
i8 : F1 = Icurves1 * random(source Icurves1, R^{-6})
o8 = {0} | -11819a4b2+8360a3b3+3907a2b4-8514a4bc-14089a3b2c+634a2b3c-15791ab4c+11189a4c2+14165a3bc2-9127a2b2c2-8632ab3c2-3147b4c2+8312a3c3+10072a2bc3-11563ab2c3-13293b3c3+2153a2c4-11866abc4-8437b2c4 |
1 1
o8 : Matrix R <--- R |
i9 : betti F1
o9 = total: 1 1
0: 1 .
1: . .
2: . .
3: . .
4: . .
5: . 1
o9 : Net |
We now look for the equation {\tt F2} of {\tt C2},
a curve with an ordinary triple point at
{\tt point1}. It must lie in the cube of the
ideal {\tt ipoint1}.
i10 : Icurves2 = gens (ipoint1^3)
o10 = {0} | a3 a2b ab2 b3 |
1 4
o10 : Matrix R <--- R |
i11 : F2 = Icurves2 * random(source Icurves2, R^{-6})
o11 = {0} | -4710a6+745a5b+14748a4b2+10410a3b3+5240a2b4+4785ab5+11220b6+13659a5c-8556a4bc-14128a3b2c+13699a2b3c+4927ab4c-4208b5c-13562a4c2+9775a3bc2-4050a2b2c2-1018ab3c2+11329b4c2-1097a3c3+12739a2bc3-8585ab2c3+8784b3c3 |
1 1
o11 : Matrix R <--- R |
i12 : betti F2
o12 = total: 1 1
0: 1 .
1: . .
2: . .
3: . .
4: . .
5: . 1
o12 : Net |
Finally, the equation of a curve with
a tacnode at $a=b=0$ having tangent line
$a-b=0$ there must lie in the ideal
i13 : i = ideal((a-b)^2) + (ipoint1^4)
2 2 4 3 2 2 3 4
o13 = ideal (a - 2a*b + b , a , a b, a b , a*b , b )
o13 : Ideal of R |
and adding a node at {\tt point3} we get
i14 : icurves3 = intersect(i, ipoint3^2)
2 2 2 2 2 2 2 3 4 3 2 2
o14 = ideal (a c - 2a*b*c + b c , a b*c - 2a*b c + b c, b , a*b , a b )
o14 : Ideal of R |
i15 : Icurves3 = gens icurves3
o15 = {0} | a2c2-2abc2+b2c2 a2bc-2ab2c+b3c b4 ab3 a2b2 |
1 5
o15 : Matrix R <--- R |
so
i16 : F3 = Icurves3 * random(source Icurves3, R^{-6})
o16 = {0} | 13692a4b2+8384a3b3+8537a2b4-10200ab5+7128b6+11295a4bc+1573a3b2c+2961a2b3c+15172ab4c+6873b5c-1064a4c2+4443a3bc2-12087a2b2c2+14967ab3c2+10828b4c2+6557a3c3-15804a2bc3+11937ab2c3-2690b3c3+14372a2c4+3247abc4+14372b2c4 |
1 1
o16 : Matrix R <--- R |
i17 : betti F3
o17 = total: 1 1
0: 1 .
1: . .
2: . .
3: . .
4: . .
5: . 1
o17 : Net |
It is evident from the discussion above
that {\tt C1} and {\tt C3} have gonality $\leq 5$ (indeed,
every curve of genus $7$ has gonality $\leq 5$)
and that {\tt C2} has gonality $\leq 4$. We can
establish lower bounds for the gonalities
by looking at the canonical embeddings.
The canonical series of {\tt C1} is cut out by
i18 : can1 = basis(3, intersect(
ipoint1,ipoint2,ipoint3)
)
o18 = {2} | b c 0 0 0 0 0 |
{2} | 0 0 a c 0 0 0 |
{2} | 0 0 0 0 a b c |
o18 : Matrix |
Some explanation regarding the {\tt basis} command
is needed here. {\tt can1} is a matrix whose target
is the ideal of the intersection of these three points:
i19 : target can1
o19 = image {0} | bc ac ab |
1
o19 : R - module, submodule of R |
and whose source is a free module over the coefficient ring:
i20 : source can1
ZZ 7
o20 = (-----)
31991
ZZ
o20 : ----- - module, free
31991 |
For our purposes, there are two problems with this.
The first is that we want a map where both the
source and target have the base ring $R$. This can
be accomplished by tensoring with $R$:
i21 : can1 = can1 ** R
o21 = {2} | b c 0 0 0 0 0 |
{2} | 0 0 a c 0 0 0 |
{2} | 0 0 0 0 a b c |
o21 : Matrix |
The second problem is that the image of a basis
element is not obviously in the ideal: it is represented
in terms of the generators of $I$. This can be
alleviated by applying {\tt super}: this takes
a homomorphism $f : M \rightarrow N$, where $N$ is a submodule of
a quotient module $F/I$, and returns
the homomorphism $f : M \rightarrow F/I$.
i22 : can1 = super can1
o22 = {0} | b2c bc2 a2c ac2 a2b ab2 abc |
1 7
o22 : Matrix R <--- R |
similarly, for {\tt C2} and {\tt C3}:
i23 : can2 = basis(3, ipoint1^2)
o23 = {2} | a b c 0 0 0 0 |
{2} | 0 0 0 b c 0 0 |
{2} | 0 0 0 0 0 b c |
o23 : Matrix |
i24 : can2 = super (can2 ** R)
o24 = {0} | a3 a2b a2c ab2 abc b3 b2c |
1 7
o24 : Matrix R <--- R |
i25 : can3 = basis(3, intersect(
ideal(a-b) + ipoint1^2,
ipoint3)
)
o25 = {2} | a c 0 0 0 0 0 |
{2} | 0 0 b c 0 0 0 |
{2} | 0 0 0 0 a b c |
o25 : Matrix |
i26 : can3 = super (can3 ** R)
o26 = {0} | a2c-abc ac2-bc2 b3 b2c a2b ab2 abc |
1 7
o26 : Matrix R <--- R |
These should all give embeddings of the
curves in $\P^6$, so we expect them to be
linear series of vector space dimension $7$.
Here's how to check:
i27 : betti can1
o27 = total: 1 7
0: 1 .
1: . .
2: . 7
o27 : Net |
i28 : betti can2
o28 = total: 1 7
0: 1 .
1: . .
2: . 7
o28 : Net |
i29 : betti can3
o29 = total: 1 7
0: 1 .
1: . .
2: . 7
o29 : Net |
To compute the homogeneous coordinate
rings of the canonical curves, we must
find the algebraic relations among the
generators of {\tt cani} modulo {\tt Fi}.
The coordinate ring of $\P^6$
i30 : S = (coefficientRing R)[x_0..x_6]
o30 = S
o30 : PolynomialRing |
Find the canonical ideal {\tt IC1}
of {\tt C1}, that is, the
kernel of the map $S \rightarrow R/(F1)$
defined by the canonical series.
i31 : T1 = R/ideal F1
o31 = T1
o31 : QuotientRing |
i32 : f1 = map(T1,S,substitute(can1, T1))
2 2 2 2 2 2
o32 = map(T1,S,{b c, b*c , a c, a*c , a b, a*b , a*b*c})
o32 : RingMap T1 <--- S |
i33 : IC1 = mingens ker f1
o33 = {0} | x_3x_5-x_6^2 x_2x_5-x_4x_6 x_1x_5-x_0x_6 x_3x_4-x_2x_6 x_1x_4-x_6^2 x_0x_4-x_5x_6 x_0x_3-x_1x_6 x_1x_2-x_3x_6 x_0x_2-x_6^2 x_0^2+6622x_0x_1-1390x_1^2+1013x_2^2-5140x_1x_3+9370x_2x_3+13550x_3^2-11830x_2x_4+817x_4^2-10496x_0x_5-9050x_4x_5-3732x_5^2-14534x_0x_6-1450x_1x_6+10649x_2x_6+5781x_3x_6-7823x_4x_6-3365x_5x_6-8526x_6^2 |
1 10
o33 : Matrix S <--- S |
and similarly for {\tt C2, C3}
i34 : T2 = R/ideal F2
o34 = T2
o34 : QuotientRing |
i35 : f2 = map(T2,S,substitute(can2, T2))
3 2 2 2 3 2
o35 = map(T2,S,{a , a b, a c, a*b , a*b*c, b , b c})
o35 : RingMap T2 <--- S |
i36 : IC2 = mingens ker f2
o36 = {0} | x_4x_5-x_3x_6 x_2x_5-x_1x_6 x_4^2-x_2x_6 x_3x_4-x_1x_6 x_1x_4-x_0x_6 x_3^2-x_1x_5 x_2x_3-x_0x_6 x_1x_3-x_0x_5 x_1x_2-x_0x_4 x_1^2-x_0x_3 x_0^2x_5-11377x_0x_1x_5+5417x_0x_3x_5+13650x_0x_5^2-7880x_1x_5^2-8661x_3x_5^2-15896x_5^3-3202x_0x_1x_6+2610x_0x_3x_6-10131x_0x_4x_6-9828x_2x_4x_6+8303x_0x_5x_6+2843x_1x_5x_6+4801x_3x_5x_6+3886x_5^2x_6+1662x_0x_6^2-12225x_1x_6^2-14273x_2x_6^2-1888x_3x_6^2+10224x_4x_6^2-11420x_5x_6^2+15851x_6^3 x_0^2x_3+4874x_0x_1x_5-3798x_0x_3x_5+3856x_0x_5^2+11352x_1x_5^2+12178x_3x_5^2-3669x_5^3-3202x_0^2x_6+11205x_0x_1x_6-10131x_0x_2x_6-9828x_2^2x_6+14625x_0x_3x_6+4848x_0x_4x_6+13107x_2x_4x_6-3349x_0x_5x_6+6711x_1x_5x_6-15765x_3x_5x_6-540x_5^2x_6-10332x_0x_6^2+11155x_1x_6^2+12619x_2x_6^2+6756x_3x_6^2+15023x_4x_6^2-9889x_5x_6^2+3560x_6^3 x_0^2x_1-3202x_0^2x_4-10131x_0x_2x_4-9828x_2^2x_4+7297x_0x_1x_5-6027x_0x_3x_5-9459x_0x_5^2-1893x_1x_5^2+13916x_3x_5^2-5098x_5^3+11205x_0^2x_6+9565x_0x_1x_6+4848x_0x_2x_6+13107x_2^2x_6+7929x_0x_3x_6+6049x_0x_4x_6-8227x_2x_4x_6+6504x_0x_5x_6+11547x_1x_5x_6-15193x_3x_5x_6-1692x_5^2x_6+4290x_0x_6^2-7827x_1x_6^2+1200x_2x_6^2+10806x_3x_6^2+13762x_4x_6^2-3260x_5x_6^2+491x_6^3 x_0^3-3202x_0^2x_2-10131x_0x_2^2-9828x_2^3+11205x_0^2x_4+4848x_0x_2x_4+13107x_2^2x_4-4703x_0x_1x_5+3568x_0x_3x_5+14031x_0x_5^2-5542x_1x_5^2+11994x_3x_5^2-6254x_5^3+9565x_0^2x_6-12498x_0x_1x_6+6049x_0x_2x_6-8227x_2^2x_6-4021x_0x_3x_6-1004x_0x_4x_6-7706x_2x_4x_6+15510x_0x_5x_6+1595x_1x_5x_6-4444x_3x_5x_6-12116x_5^2x_6-10852x_0x_6^2-6268x_1x_6^2+1147x_2x_6^2-14645x_3x_6^2-1025x_4x_6^2-4815x_5x_6^2+14709x_6^3 |
1 14
o36 : Matrix S <--- S |
i37 : T3 = R/ideal F3
o37 = T3
o37 : QuotientRing |
i38 : f3 = map(T3,S,substitute(can3, T3))
2 2 2 3 2 2 2
o38 = map(T3,S,{a c - a*b*c, a*c - b*c , b , b c, a b, a*b , a*b*c})
o38 : RingMap T3 <--- S |
i39 : IC3 = mingens ker f3
o39 = {0} | x_3x_5-x_2x_6 x_1x_5+x_3x_6-x_6^2 x_0x_5-x_4x_6+x_5x_6 x_3x_4-x_5x_6 x_2x_4-x_5^2 x_1x_4-x_0x_6 x_0x_3+x_3x_6-x_6^2 x_1x_2+x_3^2-x_3x_6 x_0x_2+x_2x_6-x_5x_6 x_0^2+14035x_0x_1-12401x_1^2+15628x_2^2-2468x_1x_3-3404x_2x_3-11195x_3^2+7476x_0x_4+829x_4^2+6504x_2x_5+6246x_4x_5+11267x_5^2-11638x_0x_6+2468x_1x_6-3502x_2x_6+16x_3x_6+13097x_4x_6-8211x_5x_6+7585x_6^2 |
1 10
o39 : Matrix S <--- S |
We now find the $2$-linear part of the
free resolution of {\tt IC1}
and its betti numbers.
i40 : IC1res = res(coker IC1)
1 10 25 25 10 1
o40 = S <-- S <-- S <-- S <-- S <-- S
0 1 2 3 4 5
o40 : ChainComplex |
i41 : betti IC1res
o41 = total: 1 10 25 25 10 1
0: 1 . . . . .
1: . 10 16 9 . .
2: . . 9 16 10 .
3: . . . . . 1
o41 : Net |
From this computation, and the easy
implication of Green's conjecture
explained above, we see that the
gonality of {\tt C1} is exactly 4, the
gonality of the linear series obtained by
projection from any one of the three double
points.
We now do the same for {\tt IC2} and {\tt IC3}:
i42 : IC2res = res(coker IC2)
1 14 35 35 14 1
o42 = S <-- S <-- S <-- S <-- S <-- S
0 1 2 3 4 5
o42 : ChainComplex |
i43 : betti IC2res
o43 = total: 1 14 35 35 14 1
0: 1 . . . . .
1: . 10 20 15 4 .
2: . 4 15 20 10 .
3: . . . . . 1
4: . . . . . .
o43 : Net |
i44 : IC3res = res(coker IC3)
1 10 25 25 10 1
o44 = S <-- S <-- S <-- S <-- S <-- S
0 1 2 3 4 5
o44 : ChainComplex |
i45 : betti IC3res
o45 = total: 1 10 25 25 10 1
0: 1 . . . . .
1: . 10 16 9 . .
2: . . 9 16 10 .
3: . . . . . 1
o45 : Net |
and we find that in the tacnodal case
the gonality is still 4, while in the
triple point case the gonality is 3.
Note that we could have made the computation
faster, as in the following example. In
these cases the resolution is so fast that
the speedup is not noticeable, but in
larger cases it would be worthwhile.
First clear the info computed in {\tt IC1}
i46 : IC1 = matrix entries IC1
o46 = {0} | x_3x_5-x_6^2 x_2x_5-x_4x_6 x_1x_5-x_0x_6 x_3x_4-x_2x_6 x_1x_4-x_6^2 x_0x_4-x_5x_6 x_0x_3-x_1x_6 x_1x_2-x_3x_6 x_0x_2-x_6^2 x_0^2+6622x_0x_1-1390x_1^2+1013x_2^2-5140x_1x_3+9370x_2x_3+13550x_3^2-11830x_2x_4+817x_4^2-10496x_0x_5-9050x_4x_5-3732x_5^2-14534x_0x_6-1450x_1x_6+10649x_2x_6+5781x_3x_6-7823x_4x_6-3365x_5x_6-8526x_6^2 |
1 10
o46 : Matrix S <--- S |
Now redo the resolution, this time bounding
the degree to which the computation is
carried.
i47 : IC1res = res(coker IC1, DegreeLimit => {1})
1 10 25 25 10 1
o47 = S <-- S <-- S <-- S <-- S <-- S
0 1 2 3 4 5
o47 : ChainComplex |
i48 : betti IC1res
o48 = total: 1 10 25 25 10 1
0: 1 . . . . .
1: . 10 16 9 . .
2: . . 9 16 10 .
3: . . . . . 1
o48 : Net |
Instead of computing the canonical model
of {\tt C1} directly, we could have treated
the structure
sheaf of {\tt C1} as a sheaf on the projective
plane, and compute its pushForward under
the map to $\P^6$ given by {\tt can1} (the image of
the plane under this map is a Del Pezzo
surface on which the canonical curve lies.)
This is done as follows:
i49 : ff1 = map(R,S,can1)
2 2 2 2 2 2
o49 = map(R,S,{b c, b*c , a c, a*c , a b, a*b , a*b*c})
o49 : RingMap R <--- S |
i50 : trim ideal pushForward1(ff1,coker F1)
2 2 2 2 2 2 2 2 2 2
o50 = ideal (x x - x , x x - x x , x x - x x , x x - x x , x x - x , x x - x x , x x - x x , x x - x x , x x - x , x + 6622*x x - 1390*x + 1013*x - 5140*x x + 9370*x x + 13550*x - 11830*x x + 817*x - 10496*x x - 9050*x x - 3732*x - 14534*x x - 1450*x x + 10649*x x + 5781*x x - 7823*x x - 3365*x x - 8526*x )
3 5 6 2 5 4 6 1 5 0 6 3 4 2 6 1 4 6 0 4 5 6 0 3 1 6 1 2 3 6 0 2 6 0 0 1 1 2 1 3 2 3 3 2 4 4 0 5 4 5 5 0 6 1 6 2 6 3 6 4 6 5 6 6
o50 : Ideal of S |
