"Parameter {T,g,a,c}: Endzeit T, Erdbeschleunigung g, Anfangsgeschwindigkeit (a,c), dazu Startzeit t=0 und Anfangsposition (0,0)"
{T,g,a,c}={3.2,10,15,15}
(*Zeitabhängige Funktionen: Geschwindigkeit (v,w), Position (x,y)*)
F[{v_,w_,x_,y_}]:={0,-g,v,w}
(*die rechte Seite der Differentialgleichung (System erster Ordnung)*)
EulerRS[{v_,w_,x_,y_},h_]:={v,w,x,y}+h*F[{v,w,x,y}]
Euler[h_,i_]:=Nest[Function[EulerRS[#,h]],{a,c,0,0},i]
(*Euler[h,i] berechnet die Näherung für die Funktionswerte nach i Schritten mit Schrittweite h. Unten werden Wertetabellen für den Plot erstellt.*)
Eulerlist[h_]:=Table[Euler[h,i],{i,0,Ceiling[T/h]}]
poslist[h_]:=Table[Drop[Euler[h,i],2],{i,0,Ceiling[T/h]}]
poslistexakt:=Table[{a*t,-g/2*t^2+c*t},{t,0,T,0.02}]
"Wurfbahnen, also {x[t],y[t]} geplottet im x-y-Koordinatensystem für alle berechneten Zeitpunkte, verbunden durch Geradenstücke. Man sieht die Näherungslösungen berechnet mit den Zeitschritten 0.7, 0.3 und 0.04, sowie die Bahn der exakten Lösung:"
ListLinePlot[{poslist[0.7],poslist[0.3],poslist[0.04],poslistexakt
}]
"Berechnete Daten mit Zeitschritt 0.7 (4 pro Zeitpunkt: Horizontal- und Vertikalgeschwindigkeit, Horizontal- und Vertikalposition):"
Eulerlist[0.7]
"Zum Vergleich die Werte der exakten Lösung, an den entsprechenden Zeitpunkten:"
Table[{a,-g*t+c,a*t,-g/2*t^2+c*t},{t,0,Ceiling[T/0.7]*0.7,0.7}]